quote:

---

Originally posted by tachyonv
Also, I think I recall constraining the indicator to not run at tick intervals. Are you running with intraday interval of one minute or larger, or with day, week or month intervals?

---

quote:

---

Originally posted by baab2004
Hello Tachyonv,
I was trying to load the easy language set-up for [Intraday Volatility Method. Target $500 profit/ indicators/ charting & screening] listed on the TradeStation Forum– but there is an error message that keeps flagging it – stating “there was a problem sending the command to the program” hence unable to save the easy language.
Please let me know if you have the newer version of the essay language…
And thank you so much in advance!
Ben

---

quote:

---

Originally posted by baab2004
Hello Tachyonv,
I was trying to load the easy language set-up for [Intraday Volatility Method. Target $500 profit/ indicators/ charting & screening] listed on the TradeStation Forum– but there is an error message that keeps flagging it – stating “there was a problem sending the command to the program” hence unable to save the easy language.
Please let me know if you have the newer version of the essay language…
And thank you so much in advance!
Ben

---

quote:

---

Originally posted by mushin2003
Hi Ben,
Tach isnt around at the moment. I have all his indicators loaded w/9.1 (9.33). Which of the 3 indicators are you referring to?
R

---

quote:

---

Originally posted by mushin2003
Hi Ben,
I think Tach's other thread(s) will answer your questions this thread tended to be more just about the KC_All indicator. I personally still trade using Tach's method though I have not run the scanner in 3-4 months. As tach mentioned the list rarely changes. Look at page 2 in this thread for the setup for ScanCriteria.
https://community.tradestation.com/Discussions/Topic.aspx?Topic_ID=117838&Page=2&

Rob

---

inputs:  
	AvgLength( 50),  
	AlertPct( 50),  
	UpColor( Green),  
	DownColor( Red), 
	UpTickColor( DarkCyan), 
	DownTickColor( RGB(255,128,64)) 
	 ; 
 
variables:  
	VVol( 0 ), 
	AvgVVol( 0 ), 
	TVol( 0 ), 
	AvgTVol( 0 ), 
	upT(0), 
	dnT(0), 
	vol2(0), 
	vol3(0), 
	tickColor(0), 
	AlertFactor( 1 + AlertPct * 0.01 ),  
	AlertStr( NumToStr( AlertPct, 2 ) ) ; 
	 
upT = UpTicks; 
dnT = DownTicks;	 
 
if BarType >= 2 and BarType < 5 then { not tick/minute data nor an advanced chart 
 type (Kagi, Renko, Kase, etc.) } 
	begin 
	VVol = Volume ; 
	AvgVVol = AverageFC( Volume, AvgLength ) ;  
	Plot4( VVol, "Vol" ) ; 
	Plot1( AvgVVol, "VolAvg" ) ; 
	{ Alert criteria } 
	if VVol crosses over AvgVVol * AlertFactor then 
		Alert( "Volume breaking through " + AlertStr + "% above its avg" ) ; 
		 
	end	 
else { if tick/minute data or an advanced chart type;  in the case of minute data, 
 also set the "For volume, use:" field in the Format Symbol dialog to Trade Vol or 
 Tick Count, as desired;  when using advanced chart types, Ticks returns volume if 
 the chart is built from 1-tick interval data } 
	begin 
	TVol = Ticks ; 
	AvgTVol = AverageFC( Ticks, AvgLength ) ; 
	Plot4( TVol, "Vol" ) ; 
	Plot1( AvgTVol, "VolAvg" ) ; 
	{ Alert criteria } 
	if TVol crosses over AvgTVol * AlertFactor then 
		Alert( "Volume breaking through " + AlertStr + "% above its avg" ) ; 
		 
	vol2 = upT; 
	vol3 = dnT; 
	tickColor = -1; 
	if UpTicks > DownTicks then begin; 
		vol2 = dnT; 
		vol3 = upT; 
		tickColor = 1; 
	end; 
	 
	Plot2(vol2, "TickVol1"); 
	Plot3(vol3, "TickVol2"); 
	 
	{ Color criteria } 
		 
	if tickColor = 1 then begin; 
		setPlotColor (2, DownTickColor); 
		setPlotColor (3, UpTickColor); 
	end else begin; 
		setPlotColor (3, DownTickColor); 
		setPlotColor (2, UpTickColor); 
	end; 
	 
end;	 
 
if Close > Close[1] then  
	SetPlotColor( 4, UpColor )  
else if Close < Close[1] then 
	SetPlotColor( 4, DownColor ) ; 
 
{ ** Copyright (c) 2001 - 2010 TradeStation Technologies, Inc. All rights reserved. **  
  ** TradeStation reserves the right to modify or overwrite this analysis technique  
     with each release. ** } 

select all

{  
REQUIRES TRADESTATION 8.1 OR LATER - WILL NOT EXECUTE 
CORRECTLY ON PRIOR TRADESTATION VERSIONS. 
 
EXECUTES ONLY IN RADARSCREEN for DAY INTERVAL. 
 
ekam created the original version of this indicator. 
 
Goose contributed additional improvements to my code to 
improve execution efficiency; and the initial ideas for color 
coding cells to flag significant recent data increases and 
decreases relative to long term data; and the addition of 
volatility percent columns. 
 
If/when EasyLanguage and RS permit deleting symbols via EL, then 
I will add that function as an option.  This cannot currently  
be done, insofar as I know. 
 
Refer to "TradableSymbols" Word document for additional  
information and instructions. 
 
If you discover improvements that should be made, please contact 
me via private messaging at <a href="http://www.tradestation.com" target="_blank">www.tradestation.com</a> . 
 
tachyonv (Vince Heiker) February 25, 2006 Version 5.1 build 26.  
 
© Copyright 2005 & 2006 TechSyon Group L.L.C. 
} 
 
inputs: 
 
	PriceMin 						( 9.00		) , 
	PriceMax 						( 200.00	) , 
	Avg_MO_Trade_Days				( 20		) , 
 
	ATR_Exp_Average					( true		) , 
 
	ATR_LTMonths					( 6 		) , 
	ATR_LTTarget$					( 0.50		) , 
	ATR_LTTargetPercent				( 2.00		) , 
 
	ATR_RecentDays					( 21		) , 
	ATR_RecentTarget$				( 0.75		) , 
	ATR_RecentTargetPcnt			( 2.00		) , 
 
	ATR_Reject_$			 		( 2			) , 
	ATR_Reject_Percent		 		( 2			) , 
 
	ATR_Up_Percent					( 20.00		) , 
	ATR_Down_Percent				( 20.00		) , 
 
	APR_Exp_Average					( true		) , 
 
	APR_LTMonths					( 6			) , 
	APR_LTTarget$					( 0.50		) , 
	APR_LTTargetPercent				( 2.00		) , 
 
	APR_RecentDays					( 21		) , 
	APR_RecentTarget$				( 0.75		) , 
	APR_RecentTargetPcnt			( 2.00		) , 
 
	APR_Reject_$		 			( 2			) , 
	APR_Reject_Percent 				( 2			) , 
	 
	APR_Up_Percent					( 20.00		) , 
	APR_Down_Percent				( 20.00		) , 
 
	Volume_Exp_Average				( true		) , 
 
	Volume_AvgLTMonths				( 6			) , 
	Volume_AvgLTTarget				( 400000	) , 
 
	Volume_AvgRecentDays			( 21		) , 
	Volume_AvgRecentTarget			( 600000	) , 
 
	Volume_Reject_Control			( 2			) , 
	Volume_Up_Percent				( 20.00		) , 
	Volume_Down_Percent				( 20.00		) , 
 
	Volume_TooLow_Days				( 34		) , 
	Volume_TooLow_Level				( 300000	) , 
	Volume_TooLow_Times				( 2			) , 
 
	Round_Control_$					( 2 		) , 
	Round_Control_Percent			( 2 		) ,	 
 
	AttentionColor_ATR				( rgb ( 255 , 255 , 255 ) ) , 
	AttentionColor_APR				( rgb ( 255 , 255 , 255 ) ) , 
	AttentionColor_Volume			( rgb ( 255 , 255 , 255 ) ) , 
 
	CautionColor_ATR				( rgb ( 255 , 255 ,   0 ) ) , 
	CautionColor_APR				( rgb ( 255 , 255 ,   0 ) ) , 
	CautionColor_Volume				( rgb ( 255 , 255 ,   0 ) ) , 
 
	Reject_Color					( rgb ( 255 ,   0 ,   0 ) ) , 
	Tradable_Color					( rgb ( 0   , 255 ,   0 ) ) , 
 
	InputEdits						( true		) , 
 
	AMEX_Exchange					( true		) , 
	ARCX_Exchange					( false		) , 
	BSE_Exchange					( false		) , 
	CBOE_Exchange					( false		) , 
	CBOT_Exchange					( false		) , 
	CIN_Exchange					( false		) , 
	CME_Exchange					( false		) , 
	COMEX_Exchange					( false		) , 
	FOREX_Exchange					( false		) , 
	KCBT_Exchange					( false		) , 
	MGE_Exchange					( false		) , 
	NASDAQ_Exchange					( true		) , 
	NASDS_Exchange					( false		) , 
	NYBOT_Exchange					( false		) , 
	NYMEX_Exchange					( false		) , 
	NYSE_Exchange					( true		) , 
	OSE_Exchange					( false		) , 
	OTC_Exchange					( false		) , 
	OTCBB_Exchange					( false		) , 
	PHLX_Exchange					( false		) , 
	PSX_Exchange					( false		) , 
    US_Exchange						( false		) ; 
 
var: 
	 
	LBOC							( false		) , 
	Desirable_Exchange				( false		) , 
	ExchangeName					( ""		) , 
 
	Trade_Status 					( ""		) , 
 
	double ATR_Day					( 0.00		) , 
	double True_High				( 0 		) , 
	double True_Low					( 0			) , 
	double TR_Day					( 0			) , 
 
	double ATR_Change				( 0.0000	) , 
 
	double ATR_LT$					( 0.00		) , 
	double ATR_LTPercent			( 0.00		) , 
	double ATR_LTSmooth				( 0.00		) , 
	ATR_LTDays						( 0.00		) , 
 
	double ATR_Recent$				( 0.00		) , 
	double ATR_RecentPcnt			( 0.00		) , 
	double ATR_RecentSmooth			( 0.00		) , 
 
	double True_Range				( 0.00		) , 
 
	double APR_Change				( 0.0000	) , 
 
	double APR_LT$					( 0.00		) , 
	double APR_LTPercent			( 0.00		) , 
	double APR_LTSmooth				( 0.00		) , 
	APR_LTDays						( 0.00		) , 
 
	double APR_Recent$				( 0.00		) , 
	double APR_RecentPcnt			( 0.00		) , 
	double APR_RecentSmooth			( 0.00		) , 
 
	double VolumeChange				( 0.0000	) , 
 
	VolumeAverageLT					( 0			) , 
	double VolumeAvgLTSmooth		( 0.00		) , 
	VolumeAvgLTDays					( 0.00		) , 
 
	VolumeAverageRecent				( 0			) , 
	double VolumeAvgRcntSmooth		( 0.00		) , 
 
	Times_Vol2Low					( 0			) , 
 
	Close_Fail						( true		) , 
	Exchange_Fail					( true		) , 
 
	ATR_LT$_Fail					( true 		) , 
	ATR_Recent$_Fail				( true 		) , 
	ATR_LTPercent_Fail				( true 		) , 
	ATR_RecentP_Fail				( true 		) , 
 
	APR_LT$_Fail					( true 		) , 
	APR_Recent_Fail$				( true 		) , 
	APR_LTPercent_Fail				( true 		) , 
	APR_RecentP_Fail				( true 		) , 
 
	VolAvgLT_Fail					( true 		) , 
	VolAvgRecent_Fail				( true		) , 
 
	Vol2Low_Fail					( true		) , 
 
	Close_Color						( rgb ( 0 , 0 , 0 ) ) , 
	Exchange_Color					( rgb ( 0 , 0 , 0 ) ) , 
	Trade_Status_Color				( rgb ( 0 , 0 , 0 ) ) , 
 
	ATR_LT$_Color					( rgb ( 0 , 0 , 0 ) ) , 
	ATR_Recent$_Color				( rgb ( 0 , 0 , 0 ) ) , 
	ATR_LTPercent_Color				( rgb ( 0 , 0 , 0 ) ) , 
	ATR_RecentP_Color				( rgb ( 0 , 0 , 0 ) ) , 
 
	APR_LT$_Color					( rgb ( 0 , 0 , 0 ) ) , 
	APR_Recent$_Color				( rgb ( 0 , 0 , 0 ) ) , 
	APR_LTPercent_Color				( rgb ( 0 , 0 , 0 ) ) , 
	APR_RecentP_Color				( rgb ( 0 , 0 , 0 ) ) , 
 
	VolAvgLT_Color					( rgb ( 0 , 0 , 0 ) ) , 
	VolAvgRecent_Color				( rgb ( 0 , 0 , 0 ) ) , 
 
	Vol2Low_Color					( rgb ( 0 , 0 , 0 ) ) , 
 
	Chart							( false		) , 
	Chart_or_RadarScreen			( 0			) , 
	RadarScreen						( false		) ; 
 
{   ______________________________________________________________ 
	|	Edits and housekeeping. 
	|_____________________________________________________________ 
} 
 
if  bartype <> 2 then 
	raiseruntimeerror ( "All symbols must be set to day interval" ) ; 
 
if  currentbar = 1 then	begin 
		 
		Chart_or_RadarScreen = getappinfo ( aiapplicationtype ) ; 
	 
		if Chart_or_RadarScreen = 1 then 
			Chart = true 
		else 
			Chart = false ; 
	 
		if Chart_or_RadarScreen = 2 then 
			RadarScreen = true 
		else 
			RadarScreen = false ; 
	 
		if  RadarScreen = false then 
			raiseruntimeerror  
			("This indicator runs only in RadarScreen." ) ; 
	 
end ; 
 
if  currentbar = 1 and InputEdits then begin		 
 
		if  PriceMin < 0 or PriceMin > PriceMax then 
			RaiseRunTimeError( "PriceMin must be >= 0 and <= PriceMax" ) ; 
		 
		if  PriceMax < 0 or PriceMax < PriceMin then 
			RaiseRunTimeError( "PriceMax must be >= 0 and >= PriceMin" ) ; 
		 
		if  APR_LTMonths <= 0 then 
			RaiseRunTimeError( "APR_LTMonths must be > 0" ) ; 
		 
		if  APR_LTTarget$ <= 0 then 
			RaiseRunTimeError( "APR_LTTarget$ must be > 0" ) ; 
		 
		if  APR_LTTargetPercent <= 0 then 
			RaiseRunTimeError( "APR_LTTargetPercent must be > 0" ) ; 
		 
		if  APR_RecentDays <= 0 or APR_RecentDays >= Avg_MO_Trade_Days * APR_LTMonths then 
			RaiseRunTimeError( "APR_RecentDays must be > 0 and " +	"< Avg_MO_Trade_Days * APR_LTMonths" ) ; 
		 
		if  APR_RecentTarget$ <= 0 then 
			RaiseRunTimeError( "APR_RecentTarget$ must be > 0" ) ; 
		 
		if  APR_RecentTargetPcnt <= 0 then 
			RaiseRunTimeError( "APR_RecentTargetPcnt must be > 0" ) ; 
		 
		if  APR_Reject_$ <> 0 and APR_Reject_$ <> 1 and 
	 		APR_Reject_$ <> 2 and APR_Reject_$ <> 3 and	APR_Reject_$ <> 4 then 
			RaiseRunTimeError( "APR_Reject_$ must be = 0, 1, 2, 3 or 4" ) ; 
			 
		if  APR_Reject_Percent <> 0 and	APR_Reject_Percent <> 1 and 
	 		APR_Reject_Percent <> 2 and	APR_Reject_Percent <> 3 and 
	 		APR_Reject_Percent <> 4 then 
			RaiseRunTimeError( "APR_Reject_Percent must be = " + "0, 1, 2, 3 or 4" ) ; 
			 
		if  APR_Up_Percent <= 0 then 
			RaiseRunTimeError( "APR_Up_Percent must be > 0" ) ; 
			 
		if  APR_Down_Percent <= 0 or APR_Down_Percent >= 100 then 
			RaiseRunTimeError( "APR_Down_Percent must be > 0 " + "and < 100" ) ; 
		 
		if  Avg_MO_Trade_Days < 19 or Avg_MO_Trade_Days > 31 then 
			RaiseRunTimeError( "Avg_MO_Trade_Days must be <=31 and >= 15" ) ; 
		 
		if  ATR_LTMonths <= 0 then 
			RaiseRunTimeError( "ATR_LTMonths must be > 0" ) ; 
		 
		if  ATR_LTTarget$ <= 0 then 
			RaiseRunTimeError( "ATR_LTTarget$ must be > 0" ) ; 
		 
		if  ATR_LTTargetPercent <= 0 then 
			RaiseRunTimeError( "ATR_LTTargetPercent must be > 0" ) ; 
		 
		if  ATR_RecentDays <= 0 or ATR_RecentDays >= Avg_MO_Trade_Days * ATR_LTMonths then 
			RaiseRunTimeError( "ATR_RecentDays must be > 0 and " +	"< Avg_MO_Trade_Days * ATR_LTMonths" ) ; 
		 
		if  ATR_RecentTarget$ <= 0 then 
			RaiseRunTimeError( "ATR_RecentTarget$ must be > 0" ) ; 
			 
		if  ATR_RecentTargetPcnt <= 0 then 
			RaiseRunTimeError( "ATR_RecentTargetPcnt must be > 0" ) ; 
		 
		if  ATR_Reject_$ <> 0 and ATR_Reject_$ <> 1 and	ATR_Reject_$ <> 2 and 
			ATR_Reject_$ <> 3 and ATR_Reject_$ <> 4 then 
			RaiseRunTimeError( "ATR_Reject_$ must be = 0, 1, 2, 3 or 4" ) ; 
			 
		if  ATR_Reject_Percent <> 0 and	ATR_Reject_Percent <> 1 and 
	 		ATR_Reject_Percent <> 2 and	ATR_Reject_Percent <> 3 and 
	 		ATR_Reject_Percent <> 4 then 
			RaiseRunTimeError( "ATR_Reject_Percent must be = " + "0, 1, 2, 3 or 4" ) ; 
		 
		if  ATR_Up_Percent <= 0 then 
			RaiseRunTimeError( "ATR_Up_Percent must be > 0" ) ; 
			 
		if  ATR_Down_Percent <= 0 or ATR_Down_Percent >= 100 then 
			RaiseRunTimeError( "ATR_Down_Percent must be > 0 " + "and < 100" ) ; 
					 
		if  Volume_AvgLTMonths <= 0 then 
			RaiseRunTimeError( "Volume_AvgLTMonths must be > 0" ) ; 
			 
		if  Volume_AvgLTTarget <= 0 then 
			RaiseRunTimeError( "Volume_AvgLTTarget must be > 0" ) ; 
		 
		if  Volume_AvgRecentDays <=0 or Volume_AvgRecentDays >= Avg_MO_Trade_Days * Volume_AvgLTMonths then 
			RaiseRunTimeError( " Volume_AvgRecentDays must be > 0 and " + "< Avg_MO_Trade_Days * Vol_AverageMonths" ) ; 
		 
		if  Volume_AvgRecentTarget <= 0 then 
			RaiseRunTimeError( "Volume_AvgRecentTarget must be > 0" ) ; 
			 
		if  Volume_Reject_Control <> 0 and Volume_Reject_Control <> 1 and 
	 		Volume_Reject_Control <> 2 and Volume_Reject_Control <> 3 and 
			Volume_Reject_Control <> 4 then 
			RaiseRunTimeError( "Volume_Reject_Control must be = " +	"0, 1, 2, 3 or 4" ) ; 
		 
		if  Volume_Up_Percent <= 0 then 
			RaiseRunTimeError( "Volume_Up_Percent must be > 0" ) ; 
		 
		if  Volume_Down_Percent <= 0 or	Volume_Down_Percent >= 100 then 
			RaiseRunTimeError( "Volume_Down_Percent must be > 0 " + "and < 100" ) ;		 
		 
		if  Volume_TooLow_Days	<= 0 or	Volume_TooLow_Days > 34 then 
			RaiseRunTimeError( "Volume_TooLow_Days Invalid" ) ; 
		 
		if  Volume_TooLow_Level	<= 0 or	Volume_TooLow_Level > 10000000 then 
			RaiseRunTimeError( "Volume_TooLow_Level Invalid" ) ; 
		 
		if  Volume_TooLow_Times	<= 0 or	Volume_TooLow_Times > 1000 then 
			RaiseRunTimeError( "Volume_TooLow_Times Invalid" ) ;	 
		 
		if  Round_Control_$ > 6 or Round_Control_$ < 0 then 
			RaiseRunTimeError ( "Round_Control_$ input wrong (0-6)" ) ; 
		 
		if  Round_Control_Percent > 6 or Round_Control_Percent < 0 then 
			RaiseRunTimeError ( "Round_Control_Percent input wrong (0-6)" ) ; 
end ; 
	 
LBOC = date = juliantodate ( lastcalcjdate ) and time = 100 * Mod  
	( IntPortion ( LastCalcMMTime / 60 ) , 24 ) + ( LastCalcMMTime - 60 * IntPortion ( LastCalcMMTime / 60 ) ) ; 
 
{   ______________________________________________________________ 
	|	Calculations. 
	|_____________________________________________________________ 
} 
			 
if  currentbar = 1 then	begin 
 
		APR_LTDays = APR_LTMonths * Avg_MO_Trade_Days ; 
 
		if  APR_Exp_Average then begin 
				 
				APR_LTSmooth = round ( 2 / ( APR_LTMonths * Avg_MO_Trade_Days + 1 ) , Round_Control_$ ) ; 
				APR_RecentSmooth = round ( 2 / ( APR_RecentDays + 1 ) , Round_Control_$ ) ; 
		end ; 
 
		ATR_LTDays = ATR_LTMonths * Avg_MO_Trade_Days ; 
 
		if  ATR_Exp_Average then begin 
				 
				ATR_LTSmooth = round ( 2 / ( ATR_LTMonths * Avg_MO_Trade_Days + 1 ) , Round_Control_$ ) ; 
				ATR_RecentSmooth = round ( 2 / ( ATR_RecentDays + 1 ) , Round_Control_$ ) ; 
		end ; 
 
		VolumeAvgLTDays	= Volume_AvgLTMonths * Avg_MO_Trade_Days ; 
 
		if  Volume_Exp_Average then	begin 
 
				VolumeAvgLTSmooth = round ( 2 / ( Volume_AvgLTMonths * Avg_MO_Trade_Days + 1 ) , Round_Control_$ ) ; 
				VolumeAvgRcntSmooth = round ( 2 / ( Volume_AvgRecentDays + 1 ) , Round_Control_$ ) ; 
		end ; 
end ; 
 
if  APR_Exp_Average then begin 
			 
		APR_LT$ = round ( APR_LT$ [ 1 ] + APR_LTSmooth * ( high - low - APR_LT$ [ 1 ] ) , Round_Control_$ ) ; 
			 
		APR_Recent$ = round ( APR_Recent$ [ 1 ] + APR_RecentSmooth * ( high - low - APR_Recent$ [ 1 ] ) , Round_Control_$ ) ; 
end 
else if  APR_Exp_Average = false then begin 
		 
		if  currentbar >= APR_LTDays then 
			APR_LT$ = round ( averagefc2 ( ( high - low ) , 
				APR_LTDays ) , Round_Control_$ ) 
			 
		else 
		if  currentbar < APR_LTDays then 
			APR_LT$ = high - low ; 
			 
		if  currentbar >= APR_RecentDays then 
			APR_Recent$ =  
				round ( averagefc2 ( ( high - low ) ,  
				APR_RecentDays ) , Round_Control_$ ) 
			 
		else 
		if  currentbar < APR_RecentDays then 
			APR_Recent$ = high - low ; 
			 
	end ; 
 
if  LBOC then  
	begin 
	 
		if  APR_LT$ > 0 then 
			APR_Change = round  
				( ( APR_Recent$ / APR_LT$ ) * 100 , 2 )  ; 
 
		if  close > 0 then 
			begin 
 
				APR_LTPercent = round ( APR_LT$ / close * 100 , 
					Round_Control_Percent ) ; 
		 
				APR_RecentPcnt = round  
					( APR_Recent$ / close * 100 ,  
					Round_Control_Percent ) ; 
	 
			end ; 
 
	end ; 
	 
if  currentbar > 1 then 
	begin 
	 
		if  close [ 1 ] > high then  
			True_High = close [ 1 ] 
		    	 
		else 
			True_High = high ; 
		 
		if  close [ 1 ] < low then  
			True_Low = close [ 1 ]  
		 
		else 
			True_Low = low ; 
		 
		True_Range = True_High - True_Low ; 
 
	end ; 
 
if  ATR_Exp_Average and currentbar > 1 then 
	begin 
		 
		ATR_LT$ = round ( ATR_LT$ [ 1 ] + ATR_LTSmooth * 
			( True_Range - ATR_LT$ [ 1 ] ) ,  
			Round_Control_$ ) ; 
			 
		ATR_Recent$ = round  
			( ATR_Recent$ [ 1 ] + ATR_RecentSmooth *  
			( True_Range - ATR_Recent$ [ 1 ] ) ,  
			Round_Control_$ ) ; 
			 
	end 
 
else 
if  ATR_Exp_Average and currentbar = 1 then 
	begin 
	 
		ATR_LT$ = high - low ; 
		ATR_Recent$ = high - low ; 
 
	end 
 
else 
if  ATR_Exp_Average = false then 
	begin 
		 
		if  currentbar >= ATR_LTDays then 
			ATR_LT$ = round ( averagefc2 ( True_Range , 
				ATR_LTDays ) , Round_Control_$ ) 
			 
		else 
		if  currentbar < ATR_LTDays then 
			ATR_LT$ = True_Range ; 
			 
		if  currentbar >= ATR_RecentDays then 
			ATR_Recent$ = round ( averagefc2 ( True_Range , 
			ATR_RecentDays ) , Round_Control_$ ) 
			 
		else 
			if  currentbar < ATR_RecentDays then 
				ATR_Recent$ = True_Range ; 
			 
	end ; 
 
if  LBOC then 
	begin 
	 
		if  ATR_LT$ > 0 then 
			ATR_Change = round  
				( ( ATR_Recent$ / ATR_LT$ ) * 100 , 2 )  ; 
 
		if  close > 0 then 
			begin 
	 
				ATR_LTPercent = round  
					( ATR_LT$ / close * 100 ,  
					Round_Control_Percent ) ; 
 
				ATR_RecentPcnt = round  
					( ATR_Recent$ / close * 100 ,  
					Round_Control_Percent ) ; 
 
			end ; 
 
	end ; 
	 
if  Volume_Exp_Average then 
	begin 
				 
		VolumeAverageLT = round  
			( VolumeAverageLT [ 1 ] + VolumeAvgLTSmooth *  
			( volume - VolumeAverageLT [ 1 ] ) , 0 ) ; 
							 
		VolumeAverageRecent = round  
			( VolumeAverageRecent [ 1 ] + VolumeAvgRcntSmooth * 
			( volume - VolumeAverageRecent [ 1 ] ) , 0 ) ; 
				 
	end 
		 
else 
if  Volume_Exp_Average = false then 
	begin 
			 
		if  currentbar >= VolumeAvgLTDays then 
			VolumeAverageLT = round ( averagefc2 ( volume , 
				VolumeAvgLTDays ) , 0 ) 
					 
		else 
		if  currentbar < VolumeAvgLTDays then 
			VolumeAverageLT = volume ; 
			 
		if  currentbar >= Volume_AvgRecentDays then 
			VolumeAverageRecent = round ( averagefc2 ( volume , 
				Volume_AvgRecentDays ) , 0 )  
			 
		else 
		if  currentbar < Volume_AvgRecentDays then 
			VolumeAverageRecent = volume ; 
			 
	end ; 
 
if  LBOC then 
	begin 
	 
		if  VolumeAverageLT > 0 then 
			VolumeChange = round ( ( VolumeAverageRecent / 
				VolumeAverageLT ) * 100 , 2 )  ; 
 
		Times_Vol2Low = kc_fastmro2  
			( ( volume < Volume_TooLow_Level ) , 
			Volume_TooLow_Days ) ; 
 
		if  Times_Vol2Low < 0 then 
			Times_Vol2Low = 0 ; 
 
		ExchangeName = getexchangename ; 
	 
		if 	( AMEX_Exchange   and ExchangeName = "AMEX" )	or 
			( ARCX_Exchange   and ExchangeName = "ARCX" ) 	or 
			( BSE_Exchange    and ExchangeName = "BSE" ) 	or 
			( CBOE_Exchange	  and ExchangeName = "CBOE" ) 	or 
			( CBOT_Exchange	  and ExchangeName = "CBOT" ) 	or 
			( CIN_Exchange    and ExchangeName = "CIN" ) 	or 
			( CME_Exchange    and ExchangeName = "CME" ) 	or 
			( COMEX_Exchange  and ExchangeName = "COMEX" )	or 
			( FOREX_Exchange  and ExchangeName = "FOREX" ) 	or 
			( KCBT_Exchange   and ExchangeName = "KCBT" ) 	or 
			( MGE_Exchange    and ExchangeName = "MGE" ) 	or 
			( NASDAQ_Exchange and ExchangeName = "NASDAQ" )	or 
			( NASDS_Exchange  and ExchangeName = "NASDS" ) 	or 
			( NYBOT_Exchange  and ExchangeName = "NYBOT" ) 	or 
			( NYMEX_Exchange  and ExchangeName = "NYMEX" ) 	or 
			( NYSE_Exchange	  and ExchangeName = "NYSE" ) 	or 
			( OSE_Exchange    and ExchangeName = "OSE" ) 	or 
			( OTC_Exchange    and ExchangeName = "OTC" ) 	or 
			( OTCBB_Exchange  and ExchangeName = "OTCBB" ) 	or 
			( PHLX_Exchange   and ExchangeName = "PHLX" ) 	or 
			( US_Exchange     and ExchangeName = "US" ) then 
			Desirable_Exchange = true 
 
		else 
			Desirable_Exchange = false ; 
 
	end ; 
 
{   ______________________________________________________________ 
	|	Filtering. 
	|_____________________________________________________________ 
} 
 
if  LBOC then 
	begin 
					 
		if  Desirable_Exchange = false then	begin 
			Exchange_Color = Reject_Color ; 
			Exchange_Fail = true ; 
		end 
		else begin	 
			Exchange_Color = Tradable_Color ; 
			Exchange_Fail = false ; 
		end ; 
 
		if  ( close < PriceMin or close >= PriceMax ) then	begin 
			Close_Color = Reject_Color ; 
			Close_Fail = true ; 
		end 
		else begin 
			Close_Color = Tradable_Color ; 
			Close_Fail = false ; 
		end ; 
 
		if  APR_LT$ < APR_LTTarget$ then begin 
			APR_LT$_Color = Reject_Color ; 
			APR_LT$_Fail = true ; 
		end 
		else begin 
			APR_LT$_Color = Tradable_Color ; 
			APR_LT$_Fail = false ; 
		end ; 
 
		if  APR_LTPercent < APR_LTTargetPercent then begin 
			APR_LTPercent_Color = Reject_Color ; 
			APR_LTPercent_Fail = true ; 
		end 
		else begin 
			APR_LTPercent_Color = Tradable_Color ; 
			APR_LTPercent_Fail = false ; 
		end ; 
 
		if APR_Recent$ < APR_RecentTarget$ then	begin 
			APR_Recent$_Color = Reject_Color  ; 
			APR_Recent_Fail$ = true ; 
		end 
		else begin 
			APR_Recent$_Color = Tradable_Color  ; 
			APR_Recent_Fail$ = false ; 
		end ; 
 
		if  APR_RecentPcnt < APR_RecentTargetPcnt then	begin 
			APR_RecentP_Color = Reject_Color ; 
			APR_RecentP_Fail = true ; 
		end 
		else begin 
			APR_RecentP_Color = Tradable_Color ; 
			APR_RecentP_Fail = false ; 
		end ; 
 
		if  ATR_LT$ < ATR_LTTarget$ then begin 
			ATR_LT$_Color = Reject_Color ; 
			ATR_LT$_Fail = true ; 
		end 
		else begin 
			ATR_LT$_Color = Tradable_Color ; 
			ATR_LT$_Fail = false ; 
		end ; 
 
		if  ATR_LTPercent < ATR_LTTargetPercent then begin 
			ATR_LTPercent_Color = Reject_Color ; 
			ATR_LTPercent_Fail = true ; 
		end 
		else begin 
			ATR_LTPercent_Color = Tradable_Color ; 
			ATR_LTPercent_Fail = false ; 
		end ; 
 
		if  ATR_Recent$ < ATR_RecentTarget$ then begin 
			ATR_Recent$_Color = Reject_Color  ; 
			ATR_Recent$_Fail = true ; 
		end 
		else begin 
			ATR_Recent$_Color = Tradable_Color  ; 
			ATR_Recent$_Fail = false ; 
		end ; 
 
		if  ATR_RecentPcnt < ATR_RecentTargetPcnt then	begin 
			ATR_RecentP_Color = Reject_Color ; 
			ATR_RecentP_Fail = true ; 
		end 
		else begin 
			ATR_RecentP_Color = Tradable_Color ; 
			ATR_RecentP_Fail = false ; 
		end ; 
 
		if  VolumeAverageLT < Volume_AvgLTTarget then begin 
			VolAvgLT_Color = Reject_Color ; 
			VolAvgLT_Fail = true ; 
		end 
		else begin 
			VolAvgLT_Color = Tradable_Color ; 
			VolAvgLT_Fail = false ; 
		end ; 
 
		if  VolumeAverageRecent < Volume_AvgRecentTarget then begin 
			VolAvgRecent_Color = Reject_Color ; 
			VolAvgRecent_Fail = true ; 
		end 
		else begin 
			VolAvgRecent_Color = Tradable_Color ; 
			VolAvgRecent_Fail = false ; 
		end ; 
 
		if  Times_Vol2Low >= Volume_TooLow_Times then begin 
			Vol2Low_Color = Reject_Color ; 
			Vol2Low_Fail = true ; 
		end 
		else begin 
			Vol2Low_Color = Tradable_Color ; 
			Vol2Low_Fail = false ; 
		end ; 
 
{   ______________________________________________________________ 
	|	Reject controls 
	|_____________________________________________________________ 
} 
 
		if  Exchange_Fail or Close_Fail or 
			( APR_Reject_$ = 1 and 
			( APR_Recent_Fail$ or APR_LT$_Fail ) ) or 
			( APR_Reject_$ = 2 and 
			APR_Recent_Fail$ and APR_LT$_Fail ) or 
			( APR_Reject_$ = 3 and APR_LT$_Fail ) or 
			( APR_Reject_$ = 4 and APR_Recent_Fail$ ) or 
			( APR_Reject_Percent = 1 and  
			( APR_LTPercent_Fail or APR_RecentP_Fail ) ) or 
			( APR_Reject_Percent = 2 and  
			APR_LTPercent_Fail and APR_RecentP_Fail ) or 
			( APR_Reject_Percent = 3 and APR_LTPercent_Fail ) or 
			( APR_Reject_Percent = 4 and APR_RecentP_Fail ) or 
			( ATR_Reject_$ = 1 and 
			( ATR_Recent$_Fail or ATR_LT$_Fail ) ) or 
			( ATR_Reject_$ = 2 and 
			ATR_Recent$_Fail and ATR_LT$_Fail ) or 
			( ATR_Reject_$ = 3 and ATR_LT$_Fail ) or 
			( ATR_Reject_$ = 4 and ATR_Recent$_Fail ) or 
			( ATR_Reject_Percent = 1 and  
			( ATR_LTPercent_Fail or ATR_RecentP_Fail ) ) or 
			( ATR_Reject_Percent = 2 and  
			ATR_LTPercent_Fail and ATR_RecentP_Fail ) or 
			( ATR_Reject_Percent = 3 and ATR_LTPercent_Fail ) or 
			( ATR_Reject_Percent = 4 and ATR_RecentP_Fail ) or 
			( Volume_Reject_Control = 1 and 
			( VolAvgLT_Fail	or VolAvgRecent_Fail ) ) or 
			( Volume_Reject_Control = 2 and 
			VolAvgLT_Fail and VolAvgRecent_Fail ) or 
			( Volume_Reject_Control = 3 and VolAvgLT_Fail ) or  
			( Volume_Reject_Control = 4 and VolAvgRecent_Fail ) or 
			 
			Vol2Low_Fail then begin 
				Trade_Status_Color = Reject_Color ; 
				Trade_Status = "REJECT" ;			 
			end 
			else begin 
				Trade_Status_Color = Tradable_Color ; 
				Trade_Status = "TRADABLE" ;			 
			end ; 
 
		if  Trade_Status = "TRADABLE" then	begin 
				if  APR_Change < ( 100 - APR_Down_Percent ) then begin 
						 
						if  APR_RecentP_Color <> Reject_Color then 
							APR_RecentP_Color = AttentionColor_APR ; 
 
						if  APR_LT$_Color <> Reject_Color then 
							APR_LT$_Color = AttentionColor_APR ; 
				end  
				else if  APR_Change > ( 100 + APR_Up_Percent ) then	begin 
					 
						if  APR_RecentP_Color <> Reject_Color then 
							APR_RecentP_Color = CautionColor_APR ; 
 
						if  APR_LT$_Color <> Reject_Color then 
							APR_LT$_Color = CautionColor_APR ; 
				end 
				else begin 
						if  APR_RecentP_Color <> Reject_Color then 
							APR_RecentP_Color = Tradable_Color ; 
 
						if  APR_LT$_Color <> Reject_Color then 
							APR_LT$_Color = Tradable_Color ; 
				end ; 
 
				if  ATR_Change < ( 100 - ATR_Down_Percent ) then begin 
						 
						if  ATR_RecentP_Color <> Reject_Color then 
							ATR_RecentP_Color = AttentionColor_ATR ; 
 
						if  ATR_LT$_Color <> Reject_Color then 
							ATR_LT$_Color = AttentionColor_ATR ; 
				end  
				else if  ATR_Change > ( 100 + ATR_Up_Percent ) then	begin 
					 
						if  ATR_RecentP_Color <> Reject_Color then 
							ATR_RecentP_Color = CautionColor_ATR ; 
 
						if  ATR_LT$_Color <> Reject_Color then 
							ATR_LT$_Color = CautionColor_ATR ; 
				end 
				else begin 
						 
						if  ATR_RecentP_Color <> Reject_Color then 
							ATR_RecentP_Color = Tradable_Color ; 
 
						if  ATR_LT$_Color <> Reject_Color then 
							ATR_LT$_Color = Tradable_Color ; 
				end ; 
 
				if  VolumeChange < ( 100 - Volume_Down_Percent ) then begin 
						 
						if  VolAvgRecent_Color <> Reject_Color then 
							VolAvgRecent_Color = AttentionColor_Volume ; 
	 
						if	VolAvgLT_Color <> Reject_Color then 
							VolAvgLT_Color = AttentionColor_Volume ; 
				end 
				else if  VolumeChange >	( 100 + Volume_Up_Percent ) then begin 
					 
						if  VolAvgRecent_Color <> Reject_Color then 
							VolAvgRecent_Color = CautionColor_Volume ; 
	 
						if	VolAvgLT_Color <> Reject_Color then 
							VolAvgLT_Color = CautionColor_Volume ; 
				end  
				else begin 
					 
						if  VolAvgRecent_Color <> Reject_Color then 
							VolAvgRecent_Color = Tradable_Color ; 
	 
						if	VolAvgLT_Color <> Reject_Color then 
							VolAvgLT_Color = Tradable_Color ; 
				end ; 
 
			end ; 
 
{   ______________________________________________________________ 
	|	Plots 
	|_____________________________________________________________ 
} 
 
		plot5 ( Trade_Status , "All Filters" , Trade_Status_Color ) ; 
 
		//plot10 ( ExchangeName, "Exchange" , Exchange_Color ) ; 
 
		plot15 ( numtostr ( close , Round_Control_$ ) , "Close" ,	Close_Color ) ; 
 
		plot20 ( numtostr ( VolumeAverageLT , 0 ) , "LT Volume" , VolAvgLT_Color ) ; 
 
		plot25 ( numtostr ( VolumeAverageRecent , 0 ) , "Rcnt Volume" , VolAvgRecent_Color ) ; 
 
		plot28  ( numtostr ( Times_Vol2Low , 0 ) , "X Vol 2 Low" , Vol2Low_Color ) ; 
 
		plot30 ( numtostr ( APR_LT$ , Round_Control_$ ) , "LT$ APR" , APR_LT$_Color ) ; 
 
		plot32 ( numtostr ( APR_Recent$ , Round_Control_$ ) ,"Recent APR" , APR_Recent$_Color ) ; 
 
		plot34( numtostr ( APR_LTPercent , Round_Control_Percent ) + " %" , "LT% APR" , APR_LTPercent_Color ) ; 
 
		plot36 ( numtostr ( APR_RecentPcnt , Round_Control_Percent ) + " %" , "Recent% APR" , APR_RecentP_Color ) ; 
 
		plot40 ( numtostr ( ATR_LT$ , Round_Control_$ ) , "ATR LT$" , ATR_LT$_Color ) ; 
 
		plot42 ( numtostr ( ATR_Recent$ , Round_Control_$ ) ,"ATR Recent$" , ATR_Recent$_Color ) ; 
 
		plot44( numtostr ( ATR_LTPercent , Round_Control_Percent ) + " %" , "ATR LT%" , ATR_LTPercent_Color ) ; 
 
		plot46 ( numtostr ( ATR_RecentPcnt , Round_Control_Percent ) + " %" , "ATR Recent%" , ATR_RecentP_Color ) ; 
 
	end ; 
 
{   ______________________________________________________________ 
	|	Ensure that RadarScreen updates correctly 
	|_____________________________________________________________ 
 
} 
 
	value99 = ticks ; 
 

select all

inputs:  
	Price( numericseries ),  
	Length( numericsimple ) ; 	{ this input is assumed to be a constant >= 1; will get divide-by-zero error if Length = 0 } 
	  
vars: 
	Len(MaxList(Length, 1));		{ Length can not be < 1 }	 
	  
 
	_AverageFC = _Summation( Price, Len ) / Len ; 

select all

inputs:  Price( numericseries ), Length( numericsimple ) ; 
variables:  Sum( 0 ) ; 
 
Sum = 0 ; 
 
for Value1 = 0 to Length - 1  
	begin 
	Sum = Sum + Price[Value1] ; 
	end ; 
 
_Summation = Sum ; 
 

select all

inputs:  
	Price( numericseries ),  
	Length( numericsimple ) ; { this input is assumed to be constant } 
 
variables:  
	Sum( 0 ) ; 
 
if CurrentBar = 1 then  
	begin 
	for Value1 = 0 to Length - 1  
		begin 
		Sum = Sum + Price[Value1] ; 
		end ; 
	end 
else 
	Sum = Sum[1] + Price - Price[Length] ; 
 
if Length <> 0 then 
	 
	AverageFC2 = Sum / Length  
 
else 
	AverageFC2 = 0 ; 

select all

quote:

---

Originally posted by mushin2003
Doh I see you wanted AverageFC2:

inputs:  
	Price( numericseries ),  
	Length( numericsimple ) ; { this input is assumed to be constant } 
 
variables:  
	Sum( 0 ) ; 
 
if CurrentBar = 1 then  
	begin 
	for Value1 = 0 to Length - 1  
		begin 
		Sum = Sum + Price[Value1] ; 
		end ; 
	end 
else 
	Sum = Sum[1] + Price - Price[Length] ; 
 
if Length <> 0 then 
	 
	AverageFC2 = Sum / Length  
 
else 
	AverageFC2 = 0 ; 

select all

---