========================
Weekly Linear Regression
========================

A prerequisite for this indicator is Jose Silva's "Calendar Week
counter".
"Weekly Linear Regression" plots a weekly Linear Regression
signal on any daily chart.

---8<---------------------------

  {Weekly Linear Regression}
  {© 2004 Roy Larsen, rlarsen@man.quik.co.nz}
  {for use on daily charts with
   Jose Silva's "Calendar Week counter"}
N:=Input("Weekly Linear Regression Periods",1,99,14);
F:=Input("End of Week,  5=Friday  6=Saturday  7=Sunday",5,7,5);
Q:=Input("Display Mode,  0=Static  1=Dynamic  2=Test",0,2,2);
  {0=Display, update on Friday when possible}
  {1=Display, update on each new bar}
  {2=Backtest, update on first bar of new week}
G:=LastValue(Highest(Sum(DayOfWeek()=F,5))=5);
I:=Fml("Calendar Week counter");
I:=Abs(I-ValueWhen(2-G,1,I)); M:=G OR I>0;
F:=G OR (DayOfWeek()=F AND I=0);
A:=LastValue(Cum(1)-1)=Cum(1);
B:=LastValue(Cum(1))=Cum(1);
J:=If(F,1,If(Alert(F,2)=0 AND M,2,0));
J:=If(A+LastValue(J)>2 OR B+(Q=1)=2,1,J);
J:=If(G,1,If(Q=2 OR Cum(J)<=1,M*2,J));
K:=ValueWhen(1,J,If(J=1,C,ValueWhen(2-G,1,C)));
K:=ValueWhen(1,K>0,K);
A:=Cum(J>0);
B:=Cum(A*K*(J>0)); B:=B-ValueWhen(N+1,J,B);
D:=Cum(A*(J>0)); D:=D-ValueWhen(N+1,J,D);
F:=Cum(K*(J>0)); F:=F-ValueWhen(N+1,J,F);
G:=Cum(Pwr(A,2)*(J>0)); G:=G-ValueWhen(N+1,J,G);
I:=Pwr(D,2);
M:=Cum(K*(J>0)); M:=(M-ValueWhen(N+1,J,M))/N;
Q:=Cum(A*(J>0)); Q:=(Q-ValueWhen(N+1,J,Q))/N;
(N*B-D*F)/(N*G-I)*A+(M-Q*(N*B-D*F)/(N*G-I));

---8<---------------------------

http://www.metastocktips.co.nz/