=================
Trade Equity LC 4
=================

This is the fourth of four explorations built to report various trading
system statistics on multiple stocks using the 'Trade Equity LC'
indicator as a reference.


  {Trade Equity LC 4}
  {© 2003 Roy Larsen}
  {rlarsen@man.quik.co.nz}

Column A: B/H DwDn
---8<---------------------------
  {Maximum buy and hold drawdown}
Cn:=FmlVar("Trade Equity LC","Cn");
Cp:=FmlVar("Trade Equity LC","Cp");
Tr:=FmlVar("Trade Equity LC","Tr");
Ea:=ValueWhen(1,Cum(1)=1 {OR Cum(Tr)=1} ,C);
I :=Cum(Ea>0)=1; Ea:=LastValue(Ea);
Gl:=((Cp-Cn)*(C/Ea))-Cp; LowestSince(1,I,Gl);
---8<---------------------------

Column B: B/H +Exc
---8<---------------------------
  {Maximum buy and hold profitable excursion}
Cn:=FmlVar("Trade Equity LC","Cn");
Cp:=FmlVar("Trade Equity LC","Cp");
Tr:=FmlVar("Trade Equity LC","Tr");
Ea:=ValueWhen(1,Cum(1)=1 {OR Cum(Tr)=1} ,C);
I :=Cum(Ea>0)=1; Ea:=LastValue(Ea);
Gl:=((Cp-Cn)*(C/Ea))-Cp; HighestSince(1,I,Gl);
---8<---------------------------

Column C: AvgeWin
---8<---------------------------
  {Average win}
Xs:=FmlVar("Trade Equity LC","Xs");
Gn:=Cum((Xs>0)*Xs); Up:=Cum(Xs>0);
Up:=If(Up=0,-1,Up); Gn:=If(Up=0,1,Gn);
If(Gn/Up=-1,0,Gn/Up);
---8<---------------------------

Column D: AvgeLoss
---8<---------------------------
  {Average loss}
Ex:=FmlVar("Trade Equity LC","Ex");
Lb:=FmlVar("Trade Equity LC","Lb");
Xd:=FmlVar("Trade Equity LC","Xd");
Ls:=Cum((Xd<0)*Xd);
Dn:=Cum(Xd<=0 AND (Ex OR Lb));
Dn:=If(Dn=0,-1,Dn); Ls:=If(Dn=0,-1,Ls);
If(Ls/Dn>0,0,Ls/Dn);
---8<---------------------------

Column E: GL Ratio
---8<---------------------------
  {Average gain/loss ratio}
Ex:=FmlVar("Trade Equity LC","Ex");
Lb:=FmlVar("Trade Equity LC","Lb");
Xs:=FmlVar("Trade Equity LC","Xs");
Xd:=FmlVar("Trade Equity LC","Xd");
Gn:=Cum((Xs>0)*Xs); Up:=Cum(Xs>0);
Ls:=Cum((Xd<0)*Xd); Ok:=Gn>0 AND Ls<0;
Dn:=Cum(Xd<=0 AND (Ex OR Lb));
Gn:=If(Ok,Gn,-1); Ls:=If(Ok,Ls,1);
Up:=If(Ok,Up,1); Dn:=If(Ok,Dn,1);
Op:=(Gn/Up)/Abs(Ls/Dn); If(Op<0,0,PREC(Op,2));
---8<---------------------------

Column F: PkTrough
---8<---------------------------
  {Maximum $ peak-to-trough range}
I :=FmlVar("Trade Equity LC","I");
Nd:=FmlVar("Trade Equity LC","Nd");
Tr:=FmlVar("Trade Equity LC","Tr");
A :=If(Tr,HighestSince(1,Tr=0,Nd),0);
B :=If(Tr,LowestSince(1,Tr=0,Nd),0);
HighestSince(1,I,If(Tr,A-B,0));
---8<---------------------------

http://www.metastocktips.co.nz/