===================
Daily Fractal Down
===================

A prerequisite for this indicator is Jose Silva's "Calendar Day
counter".
"Daily Fractal Down" plots a daily fractal down signal on any
intraday chart with sufficient historical data.

---8<---------------------------

  {Daily Fractal Down}
  {© 2004 Roy Larsen, rlarsen@man.quik.co.nz}
  {for use on intraday charts with
   Jose Silva's "Calendar Day counter"}
A:=Input("Hour of Last Daily Bar"  ,0,23,16);
B:=Input("Minute of Last Daily Bar",0,59,00);
Q:=Input("Display Mode,  0=Static  1=Dynamic  2=Test",0,2,2);
  {0=Display, update at last bar of day}
  {1=Display, update on each new bar}
  {2=Backtest, update on first bar of new day}
G:=LastValue(Highest(Sum(DayOfWeek()<>
   ValueWhen(2,1,DayOfWeek()),5))=5);
I:=Fml("Calendar Day counter");
I:=Abs(I-ValueWhen(2-G,1,I)); M:=G OR I>0;
F:=G OR (Hour()=A AND Minute()=B);
A:=LastValue(Cum(1)-1)=Cum(1);
B:=LastValue(Cum(1))=Cum(1);
J:=If(F,1,If(Alert(F,2)=0 AND M,2,0));
J:=If(A+LastValue(J)>2 OR B+(Q=1)=2,1,J);
J:=If(G,1,If(Q=2 OR Cum(J)<=1,M*2,J));
L0:=LowestSince(1,M,L);
L0:=ValueWhen(1,J,If(J=1,L0,ValueWhen(2-G,1,L0)));
L1:=ValueWhen(2,J,L0);
L2:=ValueWhen(3,J,L0);
L3:=ValueWhen(4,J,L0);
L4:=ValueWhen(5,J,L0);
L5:=ValueWhen(6,J,L0);
Single:=L2<L4 AND L2<L3 AND L2<L1;
Double:=L2<L5 AND L2<L4 AND L2=L3 AND L2<L1;
ValueWhen(1,Single OR Double,L2);

---8<---------------------------

http://www.metastocktips.co.nz/