==============
TE Entry Price
==============

This indicator gives an entry price signal that nominally matches the
binary 'Enter Long' signal of the 'PS Fractal Trading System' system
tests in MetaStock. The 'Trade Equity' family of indicators can use
either price or binary signals and this indicat or is useful for
demonstrating entries where the entry signal is also the entry price
(stop).

Note that it makes no pretence of being a valid system entry
and should not be treated as such.

---8<---------------------------

  {TE Entry Price}
  {rlarsen@man.quik.co.nz}
  {use for 'Trade Stop Light' demonstration}
F1:=ValueWhen(1,H<Ref(H,-2) AND Ref(H,-1)<Ref(H,-2) AND
Ref(H,-3)<Ref(H,-2) AND Ref(H,-4)<Ref(H,-2),Ref(H,-2));
Buy:=Cross(H,F1);
Target:=If((F1>=0.1 AND F1<0.5),F1+.005,
If(F1<0.1,F1+.001,F1+.01));
If(Buy,Max(O,Min(H,Target)),0);

---8<---------------------------


================
Trade Stop Light
================

This indicator can be used to create system exits that add percentage
profit or loss targets to an existing exit strategy. A limitation of
this 'Light' version is that the exit must be based on the CLOSE. Other
versions are available which add enhanced e xit stop capability to the
'Trade Equity' family.

Display values are, entry price, profit target, stop loss and an exit
signal.

Cut and paste the 'TE Entry Price' indicator before attempting to
cut and paste 'Trade Stop Light'.

---8<---------------------------

  {Trade Stop Light}
  {V4.2 long, © 2003 Roy Larsen}
  {rlarsen@man.quik.co.nz}
No:=Input("Entry Price 1=O 2=C 3=H 4=L",1,4,2);
Nd:=Input("Entry Delay",0,3,0);
Xd:=Input(" Exit Delay",0,3,0);
Pf:=1+Input("Profit Target %",1,99,25)/100;
Lf:=1-Input("Stoploss %",1,99,10)/100;
N:= Fml("TE Entry Price")>0; {entry formula}
X:= 0; {exit formula if required}
{* end of user area *}
N:=N AND Alert(N=0,2);X:=X AND Alert(X=0,2);
N:=If(Nd=0,N,Alert(N,Nd+1) AND Alert(N,Nd)=0);
N:=If(N>0,If(No=1,O,If(No=3,H,If(No=4,L,C))),0);
X:=If(Xd=0,X,Alert(X,Xd+1) AND Alert(X,Xd)=0);
I:=Cum(N+X>-1)=1;
M:=C<Ref(C,-1);
Tr:=If(PREV<=0,N>0,If(X OR
  If(M,-1,1)*ValueWhen(1,PREV=0,N)<=
  If(M,-C/Lf,C/Pf),-1,1));
Xb:=Tr<0;
Tr:=Abs(Tr)*ValueWhen(1,I OR (Alert(Tr=0,2) AND Tr),N);
Tr; Pf*Tr; Lf*Tr; Xb;

---8<---------------------------

http://www.metastocktips.co.nz/