MetaStock -> Tools -> Indicator Builder -> New
Copy and paste formula below.


====================================
MACD oscillator - Schaff Trend Cycle
====================================
---8<---------------------------

{ Stochastic-normalized MACD v1.0, -100~+100% }
{ ©Copyright 2003 Jose Silva }
{ http://www.metastocktools.com }

pds:=Input("Stochastic (cycle) lookback periods",2,252,63);
pds1:=Input("short EMA periods",1,252,12);
pds2:=Input("long EMA periods",2,2520,26);
pds3:=Input("MACD oscillator trigger signal periods",1,252,21);
z:=Input("use Open=1 High=2 Low=3 Close=4 Volume=5 P=6",1,6,4);
plot:=Input("MACD osc=1, Hist=2, trigger crossover Signals=3",1,3,1);

z:=If(z=1,O,If(z=2,H,If(z=3,L,If(z=5,V,If(z=6,P,C)))));
x:=Mov(z,pds1,E);
y:=Mov(z,pds2,E);
ratio:=Min(x,y)/Max(x,y);
Mac:=(If(x>y,2-ratio,ratio)-1)*100;

StochMac:=(Mac-LLV(Mac,pds))
 /(HHV(Mac,pds)-LLV(Mac,pds)+.000001)*100;
trigger:=Mov(StochMac,pds3,E);
hist:=StochMac-trigger;
signals:=Cross(StochMac,trigger)
 -Cross(trigger,StochMac);

If(plot=1,50,0);
If(plot=1,trigger,0);
If(plot=1,StochMac,If(plot=2,hist,signals))

---8<---------------------------


http://www.metastocktools.com