MetaStock -> Tools -> Indicator Builder -> New
Copy and paste formula below.


===========
Force Index
===========
---8<---------------------------

{ Dr Elder's Force Index v2.0 }
{ Incorporating automatic historically-valid
  Force Index peak/trough boundaries }
{ ©Copyright 2004 Jose Silva }
{ http://www.metastocktools.com }

{ User inputs }
pds:=Input("Force Index smoothing periods",
 1,252,2);
norm:=Input("Force Index normalizing periods",
 2,2520,252);
plot:=Input("[1] Original Force Index,  [2]Normalized",1,2,2);

{ Force Index flavours }
FI:=Mov(V*(C-Ref(C,-1)),pds,E);
FInorm:=(FI-LLV(FI,norm))
 /(HHV(FI,norm)-LLV(FI,norm)+.000001)*200-100;
FI:=If(plot=1,FI,FInorm);
avg:=Cum(FI)/Cum(IsDefined(FI));

{ historical FI peak/trough boundaries }
pk:=Ref(FI,-1)>Ref(FI,-2)
 AND Ref(FI,-1)>FI
 AND Ref(FI,-1)>avg;
pkVal:=ValueWhen(1,pk,Ref(FI,-1));
pkAvg:=If(plot=1,avg,
 Cum(pkVal)/Cum(IsDefined(pkVal)));
tr:=Ref(FI,-1)<Ref(FI,-2)
 AND Ref(FI,-1)<FI
 AND Ref(FI,-1)<avg;
trVal:=ValueWhen(1,tr,Ref(FI,-1));
trAvg:=If(plot=1,avg,
 Cum(trVal)/Cum(IsDefined(trVal)));

{ Plot on own window }
pkAvg;avg;trAvg;FI

---8<---------------------------


http://www.metastocktools.com