MetaStock -> Tools -> Indicator Builder -> New
Copy and paste formula below.


=========================
EMA - Volatility adjusted
=========================
---8<---------------------------

{ Volatility-adjusted, dynamic-period EMA v2.4 }
{ EMA periodicity shortens on high volatility,
  increases on low volatility }
{ ©Copyright 2003-2004 Jose Silva }
{ http://www.metastocktools.com }

pds:=Input("EMA periods",1,2520,21);
x:=Input("use Open=1 High=2 Low=3 Close=4 Volume=5 P=6",1,6,4);
shift:=1+Input("EMA vertical shift %",
 -100,100,0)/100;
plot:=Input("EMA=1, Volatility=2, Dyn EMA pds=3, Crossovers=4",1,4,1);

x:=If(x=1,O,If(x=2,H,If(x=3,L,If(x=5,V,If(x=6,P,C)))));
Vt:=Stdev(x,5)/Mov(Stdev(x,5),10,S);
pds:=pds*.75/(Vt+.1);
pds:=If(pds>Cum(IsDefined(x))-13,
 Cum(IsDefined(x))-13,pds);
pds:=If(pds<1,1,pds);
VtEma:=x*2/(pds+1)+PREV*(1-2/(pds+1));
VtEma:=VtEma*shift;
signals:=Cross(x,VtEma)-Cross(VtEma,x);

If(plot=2,Vt*10,If(plot=3,pds,
 If(plot=4,signals,VtEma)))

---8<---------------------------


http://www.metastocktools.com